Bài 7. Kết nối ESP8266 và Arduino qua giao tiếp UART

String getValue(String data, char separator, int index){
  int found = 0;
  int strIndex[] = { 0, -1 };
  int maxIndex = data.length() - 1;

  for (int i = 0; i <= maxIndex && found <= index; i++) {
      if (data.charAt(i) == separator || i == maxIndex) {
          found++;
          strIndex[0] = strIndex[1] + 1;
          strIndex[1] = (i == maxIndex) ? i+1 : i;
      }
  }
  return found > index ? data.substring(strIndex[0], strIndex[1]) : "";
}

#include <DHTesp.h> // Thư viện cho cảm biến DHT11
#include <SoftwareSerial.h> // Thư viện cho EspSoftwareSerial

#define DHTPIN D0 // Chân kết nối với cảm biến
#define RX_PIN 4 // Chân RX của EspSoftwareSerial
#define TX_PIN 5 // Chân TX của EspSoftwareSerial

DHTesp dht; // Tạo một đối tượng DHT
SoftwareSerial mySerial(RX_PIN, TX_PIN); // Tạo một đối tượng EspSoftwareSerial

void setup() {
  Serial.begin(9600); // Khởi tạo cổng nối tiếp cứng với tốc độ baud là 9600
  mySerial.begin(9600); // Khởi tạo cổng nối tiếp mềm với tốc độ baud là 9600
  dht.setup(DHTPIN, DHTesp::DHT11); // Khởi tạo cảm biến
}

void loop() {
  delay(2000); // Đợi 2 giây

  TempAndHumidity th = dht.getTempAndHumidity(); // Đọc độ ẩm và nhiệt độ

  if (dht.getStatus() != DHTesp::ERROR_NONE) { // Kiểm tra xem có lỗi không
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  //Thiết lập Data gửi đi dạng: "35.6;71.2" 2 giá trị phân cách bởi ';'
  String Data = String(th.temperature,1) + ";" + String(th.humidity,1);
  mySerial.println(Data); //Gửi giá trị nhiệt độ và độ ẩm qua Software serial
  Serial.println(Data); //In ra Serial Monitor chuỗi gửi đi
}

#include <SoftwareSerial.h> // Thư viện cho cổng nối tiếp mềm

#define RX_PIN 10 // Chân RX của cổng nối tiếp mềm
#define TX_PIN 11 // Chân TX của cổng nối tiếp mềm

SoftwareSerial mySerial(RX_PIN, TX_PIN); // Tạo một đối tượng cổng nối tiếp mềm

// Hàm tách chuỗi dữ liệu theo ký tự phân cách và trả về phần tử thứ index
String getValue(String data, char separator, int index){
  int found = 0;
  int strIndex[] = { 0, -1 };
  int maxIndex = data.length() - 1;

  for (int i = 0; i <= maxIndex && found <= index; i++) {
      if (data.charAt(i) == separator || i == maxIndex) {
          found++;
          strIndex[0] = strIndex[1] + 1;
          strIndex[1] = (i == maxIndex) ? i+1 : i;
      }
  }
  return found > index ? data.substring(strIndex[0], strIndex[1]) : "";
}

void setup() {
  Serial.begin(9600); // Khởi tạo cổng nối tiếp cứng với tốc độ baud là 9600
  mySerial.begin(9600); // Khởi tạo cổng nối tiếp mềm với tốc độ baud là 9600
}

void loop() {
  if (mySerial.available()) { // Nếu có dữ liệu từ cổng nối tiếp mềm
    String data = mySerial.readString(); // Đọc chuỗi dữ liệu
    Serial.println(data); // In ra chuỗi dữ liệu
    String value1 = getValue(data, ';', 0); // Tách phần tử thứ 0 theo ký tự phân cách ';'
    String value2 = getValue(data, ';', 1); // Tách phần tử thứ 1 theo ký tự phân cách ';'
    Serial.println("Temperature:"+value1); // In ra phần tử thứ 0
    Serial.println("Humidity:"+value2); // In ra phần tử thứ 1
  }
}

{
  "temperature": 25.6,
  "humidity": 45.3
}

// Khai báo các thư viện cần thiết
#include <ArduinoJson.h>
#include <DHTesp.h>
#include <SoftwareSerial.h>

// Định nghĩa kiểu cảm biến DHT là DHT11 và số chân GPIO kết nối với cảm biến là 16
#define DHTTYPE DHTesp::DHT11
#define DHTPIN 16

// Tạo một đối tượng DHT để làm việc với cảm biến
DHTesp dht;

// Tạo một đối tượng JsonDocument có dung lượng 100 byte
StaticJsonDocument<100> doc;

#define RX_PIN 4 // Chân RX của EspSoftwareSerial
#define TX_PIN 5 // Chân TX của EspSoftwareSerial
// Tạo một đối tượng SoftwareSerial
SoftwareSerial mySerial(RX_PIN , TX_PIN ); // RX, TX

void setup() {
  // Khởi tạo giao tiếp nối tiếp với tốc độ baud là 9600
  Serial.begin(9600);
  // Khởi tạo cảm biến DHT
  dht.setup(DHTPIN, DHTTYPE);
  // Khởi tạo cổng nối tiếp ảo
  mySerial.begin(9600);
}

void loop() {
  // Đọc giá trị nhiệt độ và độ ẩm từ cảm biến
  float temperature = dht.getTemperature();
  float humidity = dht.getHumidity();

  // Kiểm tra xem các giá trị có hợp lệ hay không
  if (isnan(temperature) || isnan(humidity)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  // Gán giá trị nhiệt độ và độ ẩm vào đối tượng JsonDocument
  doc["temperature"] = temperature;
  doc["humidity"] = humidity;

  // Chuyển đổi đối tượng JsonDocument thành chuỗi JSON và gửi nó qua cổng nối tiếp ảo
  serializeJson(doc, mySerial);
  mySerial.println();

  // Chuyển đổi đối tượng JsonDocument thành chuỗi JSON và gửi nó qua cổng nối tiếp thật
  serializeJson(doc, Serial);
  Serial.println();

  // Đợi một giây
  delay(1000);
}

// Khai báo thư viện cần thiết
#include <ArduinoJson.h>

// Khai báo thư viện SoftwareSerial
#include <SoftwareSerial.h>

#define RX_PIN 10 // Chân RX của cổng nối tiếp mềm
#define TX_PIN 11 // Chân TX của cổng nối tiếp mềm

SoftwareSerial mySerial(RX_PIN, TX_PIN); // Tạo một đối tượng cổng nối tiếp mềm

// Tạo một đối tượng JsonDocument có dung lượng 100 byte
StaticJsonDocument<100> doc;

void setup() {
  // Khởi tạo giao tiếp nối tiếp với tốc độ baud là 9600
  Serial.begin(9600);
  // Khởi tạo cổng nối tiếp ảo
  mySerial.begin(9600);
}

void loop() {
  // Kiểm tra xem có dữ liệu nào sẵn sàng trên cổng nối tiếp ảo hay không
  if (mySerial.available()) {
    // Đọc một dòng từ cổng nối tiếp ảo
    String line = mySerial.readStringUntil('\n');

    // Chuyển đổi chuỗi JSON thành đối tượng JsonDocument
    DeserializationError error = deserializeJson(doc, line);

    // Kiểm tra xem có lỗi nào trong quá trình chuyển đổi hay không
    if (error) {
      Serial.print("deserializeJson() failed: ");
      Serial.println(error.c_str());
      return;
    }

    // Lấy giá trị nhiệt độ và độ ẩm từ đối tượng JsonDocument
    float temperature = doc["temperature"];
    float humidity = doc["humidity"];

    // In các giá trị ra màn hình nối tiếp
    Serial.print("Temperature: ");
    Serial.print(temperature);
    Serial.println(" C");
    Serial.print("Humidity: ");
    Serial.print(humidity);
    Serial.println(" %");
  }
}