Bài 1. Đồng hồ thời gian thực dùng ESP32 và màn hình OLED

#include <time.h>

// Hàm thiết lập thời gian bắt đầu
void setupTime() {
  struct tm t;
  t.tm_year = 2024 - 1900; // Năm 2024 (tính từ 1900)
  t.tm_mon = 10; // Tháng 11 (tháng bắt đầu từ 0, nên 10 là tháng 11)
  t.tm_mday = 15; // Ngày 15
  t.tm_hour = 8; // Giờ 8
  t.tm_min = 30; // Phút 30
  t.tm_sec = 0; // Giây 0
  t.tm_isdst = 0; // Không có giờ mùa hè

  time_t epoch = mktime(&t); // Chuyển đổi struct tm thành time_t (giây từ Epoch)
  struct timeval tv = {epoch, 0}; // Tạo struct timeval
  settimeofday(&tv, NULL); // Thiết lập thời gian hệ thống
}

void setup() {
  Serial.begin(115200); // Khởi động Serial với tốc độ truyền 115200 bps
  setupTime(); // Gọi hàm thiết lập thời gian ban đầu
}

void loop() {
  time_t now;
  struct tm timeinfo;
  time(&now); // Lấy thời gian hiện tại
  localtime_r(&now, &timeinfo); // Chuyển đổi thời gian hiện tại thành struct tm

  // In thời gian hiện tại ra Serial Monitor
  Serial.println(&timeinfo, "%A, %d-%m-%Y %H:%M:%S");

  delay(1000); // Đợi 1 giây
}

#include <WiFi.h>
#include <time.h>

// Định nghĩa thông tin kết nối WiFi
const char* ssid = "your_SSID"; // Tên mạng WiFi của bạn
const char* password = "your_PASSWORD"; // Mật khẩu WiFi của bạn

// Định nghĩa UTC offset cho múi giờ Việt Nam (UTC+7)
const long gmtOffset_sec = 7 * 3600; // 7 giờ * 3600 giây/giờ
const int daylightOffset_sec = 0; // Không có giờ mùa hè ở Việt Nam

void setup() {
  Serial.begin(115200); // Khởi động Serial
  WiFi.begin(ssid, password); // Kết nối WiFi
  
  // Chờ kết nối WiFi
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000); // Đợi 1 giây
    Serial.println("Connecting to WiFi...");
  }
  
  Serial.println("Connected to WiFi"); // In thông báo đã kết nối WiFi

  // Thiết lập NTP để đồng bộ thời gian với múi giờ Việt Nam
  // Tham số đầu là GMT offset (giờ lệch so với UTC), 
  // Tham số thứ hai là daylight offset (lệch giờ mùa hè),
  // Tham số thứ ba là tên server NTP để lấy thời gian
  configTime(gmtOffset_sec, daylightOffset_sec, "time.google.com");

  // Chờ đồng bộ thời gian từ server NTP
  struct tm timeinfo; // Biến để lưu thông tin thời gian
  if (!getLocalTime(&timeinfo)) { 
    Serial.println("Failed to obtain time"); 
    return; // Thoát nếu không lấy được thời gian
  }

  // In thời gian hiện tại lên Serial Monitor với thứ tự tùy chỉnh
  Serial.println(&timeinfo, "%d-%m-%Y %H:%M:%S"); 
}

void loop() {
  // Cập nhật và in thời gian hiện tại mỗi giây
  delay(1000); // Đợi 1 giây
  struct tm timeinfo; // Biến để lưu thông tin thời gian
  if (getLocalTime(&timeinfo)) { 
    Serial.println(&timeinfo, "%d-%m-%Y %H:%M:%S");
  }
}

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <WiFi.h>
#include <time.h>

// Định nghĩa chiều rộng và chiều cao của màn hình OLED
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

// Khởi tạo đối tượng màn hình OLED
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

// Định nghĩa thông tin kết nối WiFi
const char* ssid = "your_SSID";
const char* password = "your_PASSWORD";

// Định nghĩa UTC offset cho múi giờ Việt Nam (UTC+7)
const long gmtOffset_sec = 7 * 3600;
const int daylightOffset_sec = 0;

// Hàm lấy tên viết tắt của ngày trong tuần
const char* getDayAbbr(int wday) {
  switch (wday) {
    case 0: return "Sun";
    case 1: return "Mon";
    case 2: return "Tue";
    case 3: return "Wed";
    case 4: return "Thu";
    case 5: return "Fri";
    case 6: return "Sat";
    default: return "";
  }
}

void setup() {
  Serial.begin(115200);
  WiFi.begin(ssid, password);

  // Kết nối WiFi
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi...");
  }

  Serial.println("Connected to WiFi");

  // Thiết lập NTP để đồng bộ thời gian
  configTime(gmtOffset_sec, daylightOffset_sec, "time.google.com");

  // Kiểm tra và khởi động màn hình OLED
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    for (;;);
  }

  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0, 0);
  display.println("Real Time Clock");
  display.display();
  delay(2000); // Hiển thị thông điệp chào mừng trong 2 giây

  // Đồng bộ thời gian
  struct tm timeinfo;
  if (!getLocalTime(&timeinfo)) {
    Serial.println("Failed to obtain time");
    display.setCursor(0, 10);
    display.println("Failed to get time");
    display.display();
    while (1) { delay(1000); }
  }

  // In thời gian đồng bộ lên Serial Monitor
  Serial.println(&timeinfo, "%A, %B %d %Y %H:%M:%S");
}

void loop() {
  struct tm timeinfo;
  if (getLocalTime(&timeinfo)) {
    // Xóa màn hình cũ
    display.clearDisplay();

    // Hiển thị thời gian (giờ:phút:giây)
    display.setTextSize(2);
    char timeString[10];
    sprintf(timeString, "%02d:%02d:%02d", timeinfo.tm_hour, timeinfo.tm_min, timeinfo.tm_sec);
    Serial.println("Time: " + String(timeString));

    int16_t x1, y1;
    uint16_t width, height;
    display.getTextBounds(timeString, 0, 0, &x1, &y1, &width, &height);
    int16_t x = (SCREEN_WIDTH - width) / 2;
    display.setCursor(x, 0);
    display.print(timeString);

    // Hiển thị thứ và ngày (Thứ - ngày-tháng-năm)
    display.setTextSize(1);
    char dateString[20];
    sprintf(dateString, "%s - %02d/%02d/%04d", getDayAbbr(timeinfo.tm_wday), timeinfo.tm_mday, timeinfo.tm_mon + 1, timeinfo.tm_year + 1900);
    display.getTextBounds(dateString, 0, 0, &x1, &y1, &width, &height);
    x = (SCREEN_WIDTH - width) / 2;
    display.setCursor(x, 40);
    display.print(dateString);

    display.display();
  }
  delay(1000); // Cập nhật mỗi giây
}