Bài 6. Bộ nhớ FLASH trên ESP32

#include <EEPROM.h>

void setup() {
  Serial.begin(115200);
  EEPROM.begin(512);  // Khởi tạo EEPROM với 512 bytes

  // Ghi dữ liệu vào EEPROM
  EEPROM.write(0, 'A');
  EEPROM.commit();

  // Đọc dữ liệu từ EEPROM
  char value = EEPROM.read(0);
  Serial.print("Đọc từ EEPROM: ");
  Serial.println(value);
}

void loop() {
  // Không làm gì trong vòng lặp này
}

#include <EEPROM.h>  // Thư viện EEPROM

void setup() {
  Serial.begin(115200);  // Khởi động Serial Monitor với baud rate 115200
  EEPROM.begin(100);  // Khởi tạo EEPROM với dung lượng 100 bytes

  // Ghi chuỗi "Hello ESP32!" vào EEPROM từ địa chỉ 0
  EEPROM.writeString(0, "Hello ESP32!");
  EEPROM.commit();  // Ghi nội dung vào bộ nhớ Flash

  // Khai báo mảng ký tự để đọc dữ liệu từ EEPROM
  char str[15];
  // Đọc chuỗi từ EEPROM từ địa chỉ 0
  size_t bytesRead = EEPROM.readString(0, str, sizeof(str));

  // Kiểm tra và in ra dữ liệu đọc được
  if (bytesRead > 0) {
    Serial.print("Read Data: ");
    Serial.println(str);
  } else {
    Serial.println("Error reading string from EEPROM.");
  }
}

void loop() {
  // Không làm gì trong vòng lặp này
}

#include <EEPROM.h>  // Thư viện EEPROM

// Cấu trúc lưu trữ cấu hình
struct ConfigStore {
  uint8_t flags;  // Biến cờ
  char ssid[32];  // Tên mạng Wi-Fi
  char pass[64];  // Mật khẩu Wi-Fi
} __attribute__((packed));  // Đảm bảo cấu trúc được đóng gói gọn gàng

void setup() {
  Serial.begin(115200);  // Khởi động Serial Monitor với baud rate 115200

  EEPROM.begin(sizeof(ConfigStore));  // Khởi tạo EEPROM với kích thước của cấu trúc ConfigStore

  // Khởi tạo cấu trúc config với dữ liệu ban đầu
  ConfigStore config = {
    0,
    "DTM E-SMART",
    "0919890938"
  };

  // Ghi cấu trúc config vào EEPROM
  EEPROM.put(0, config);
  EEPROM.commit();  // Cam kết ghi dữ liệu vào bộ nhớ Flash

  // Xóa nội dung của config để đảm bảo đọc lại từ EEPROM
  memset(&config, 0, sizeof(config));

  // Đọc cấu trúc config từ EEPROM
  EEPROM.get(0, config);

  // In ra dữ liệu đã đọc được
  Serial.println("\nFlags: " + String(config.flags));
  Serial.println("SSID: " + String(config.ssid));
  Serial.println("PASS: " + String(config.pass));
}

void loop() {
  // Không làm gì trong vòng lặp này
}

#include <SPIFFS.h>

void setup() {
  Serial.begin(115200);

  if (!SPIFFS.begin(true)) {
    Serial.println("Lỗi khi khởi động SPIFFS");
    return;
  }

  // Ghi dữ liệu vào file
  File file = SPIFFS.open("/data.txt", FILE_WRITE);
  if (!file) {
    Serial.println("Lỗi khi mở file để ghi");
    return;
  }
  file.print("Hello, ESP32!");
  file.close();

  // Đọc dữ liệu từ file
  file = SPIFFS.open("/data.txt");
  if (!file) {
    Serial.println("Lỗi khi mở file để đọc");
    return;
  }
  while (file.available()) {
    Serial.write(file.read());
  }
  file.close();
}

void loop() {
  // Không làm gì trong vòng lặp này
}

#include <FS.h>
#include <LittleFS.h>

void setup() {
  Serial.begin(115200);

  // Khởi tạo hệ thống file LittleFS
  if (!LittleFS.begin()) {
    Serial.println("Lỗi khi khởi động LittleFS");
    return;
  }

  // Ghi dữ liệu vào file
  File file = LittleFS.open("/data.txt", FILE_WRITE);
  if (!file) {
    Serial.println("Lỗi khi mở file để ghi");
    return;
  }
  file.print("Hello, ESP32 with LittleFS!");
  file.close();
  Serial.println("Dữ liệu đã được ghi vào file.");

  // Đọc dữ liệu từ file
  file = LittleFS.open("/data.txt");
  if (!file) {
    Serial.println("Lỗi khi mở file để đọc");
    return;
  }
  Serial.println("Nội dung trong file:");
  while (file.available()) {
    Serial.write(file.read());
  }
  file.close();
}

void loop() {
  // Không làm gì trong vòng lặp này
}